QML WorkerScript Element

The WorkerScript element enables the use of threads in QML. More...

• List of all members, including inherited members

Properties

• source : url

Signals

• onMessage

Methods

• sendMessage

Detailed Description

Use WorkerScript to run operations in a new thread. This is useful for running operations in the background so that the main GUI thread is not blocked.

Messages can be passed between the new thread and the parent thread using sendMessage() and the onMessage() handler.

An example:

 import QtQuick 1.0

 Rectangle {
     width: 300; height: 300

     Text {
         id: myText
         text: 'Click anywhere'
     }

     WorkerScript {
         id: myWorker
         source: "script.js"

         onMessage: myText.text = messageObject.reply
     }

     MouseArea {
         anchors.fill: parent
         onClicked: myWorker.sendMessage({ 'x': mouse.x, 'y': mouse.y })
     }
 }

The above worker script specifies a JavaScript file, "script.js", that handles the operations to be performed in the new thread. Here is script.js:

 WorkerScript.onMessage = function(message) {
     // ... long-running operations and calculations are done here
     WorkerScript.sendMessage({ 'reply': 'Mouse is at ' + message.x + ',' + message.y })
 }

When the user clicks anywhere within the rectangle, sendMessage() is called, triggering the WorkerScript.onMessage() handler in script.js. This in turn sends a reply message that is then received by the onMessage() handler of myWorker.

Restrictions

Since the WorkerScript.onMessage() function is run in a separate thread, the JavaScript file is evaluated in a context separate from the main QML engine. This means that unlike an ordinary JavaScript file that is imported into QML, the script.js in the above example cannot access the properties, methods or other attributes of the QML item, nor can it access any context properties set on the QML object through QDeclarativeContext.

Additionally, there are restrictions on the types of values that can be passed to and from the worker script. See the sendMessage() documentation for details.

See also WorkerScript example and Threaded ListModel example.

Property Documentation

Signal Documentation

Method Documentation